ESP32 Joystick Servo Motor
Trong hướng dẫn này, chúng ta sẽ học cách sử dụng ESP32 và joystick để điều khiển hai servo motor hoặc một bộ kit xoay nghiêng (pan-tilt) với servo.
Joystick có hai potentiometer tích hợp vuông góc với nhau (gọi là trục X và trục Y). Các potentiometer này xuất ra giá trị analog (gọi là X-value và Y-value) trên các chân VRX và VRY. Chúng ta sẽ sử dụng các giá trị analog này để điều khiển hai servo motor độc lập: X-value điều khiển servo #1 và Y-value điều khiển servo #2. Trong trường hợp của bộ kit xoay nghiêng, chuyển động của hai servo motor tạo ra chuyển động 3 chiều.
Có hai trường hợp ứng dụng:
- Trường hợp 1: Servo motor xoay theo chuyển động của cần điều khiển joystick:
- Góc của servo motor tỷ lệ thuận với giá trị X-value và Y-value của joystick.
- Khi chúng ta thả cần điều khiển ⇒ tất cả giá trị trở về giá trị trung tâm ⇒ servo motor tự động trở về vị trí trung tâm
- Trường hợp 2: sử dụng joystick để ra lệnh cho servo motor (lệnh lên/xuống/trái/phải)
- Khi cần điều khiển joystick được đẩy sang trái, di chuyển servo motor #1 theo chiều kim đồng hồ từng bước
- Khi cần điều khiển joystick được đẩy sang phải, di chuyển servo motor #1 ngược chiều kim đồng hồ từng bước
- Khi cần điều khiển joystick được đẩy lên, di chuyển servo motor #2 theo chiều kim đồng hồ từng bước
- Khi cần điều khiển joystick được đẩy xuống, di chuyển servo motor #2 ngược chiều kim đồng hồ từng bước
- Khi chúng ta thả cần điều khiển joystick ⇒ servo motor sẽ không trở về vị trí trung tâm
- Nếu joystick được nhấn (nút nhấn), servo motor sẽ trở về vị trí trung tâm
- Cách kết nối ESP32 với joystick và servo motor bằng breadboard
- Cách kết nối ESP32 với joystick và servo motor bằng bo mạch chia chân terminal
- Nếu đây là lần đầu tiên bạn sử dụng ESP32, hãy xem ESP32 - Cài Đặt Phần Mềm.
- Kết nối joystick và servo motor với bo mạch ESP32 theo sơ đồ đấu dây phía trên.
- Kết nối bo mạch ESP32 với máy tính của bạn qua cáp micro USB
- Mở Arduino IDE trên máy tính của bạn.
- Chọn đúng bo mạch ESP32 (ví dụ: ESP32 Dev Module) và cổng COM.
- Click vào biểu tượng Libraries trên thanh bên trái của Arduino IDE.
- Gõ ESP32Servo trong ô tìm kiếm, sau đó tìm thư viện servo của Kevin Harrington, John K. Bennett.
- Click nút Install để cài đặt thư viện servo motor cho ESP32.
- Sao chép code phía trên và mở bằng Arduino IDE
- Click nút Upload trên Arduino IDE để upload code lên ESP32
- Mở Serial Monitor
- đẩy joystick theo một hướng nào đó
- Quan sát chuyển động của servo motor
- Xem kết quả trên Serial Monitor
- Click vào biểu tượng Libraries trên thanh bên trái của Arduino IDE.
- Tìm kiếm "ezButton", sau đó tìm thư viện button của ArduinoGetStarted.com
- Click nút Install để cài đặt thư viện ezButton.
- Sao chép code phía trên và mở bằng Arduino IDE
- Click nút Upload trên Arduino IDE để upload code lên ESP32
- Mở Serial Monitor
- đẩy joystick theo một hướng nào đó
- Quan sát chuyển động của servo motor
- Xem kết quả trên Serial Monitor
- ADC của ESP32 không hoàn toàn chính xác và có thể cần hiệu chuẩn để có kết quả đúng. Mỗi bo mạch ESP32 có thể khác nhau một chút, vì vậy bạn cần hiệu chuẩn ADC cho từng bo mạch riêng lẻ.
- Việc hiệu chuẩn có thể khó khăn, đặc biệt đối với người mới bắt đầu, và có thể không luôn cho kết quả chính xác như mong muốn.
Chúng ta sẽ khám phá code cho cả hai trường hợp trong các phần tiếp theo.
Linh Kiện Cần Thiết
| 1 | × | mô-đun phát triển ESP-WROOM-32 | ||
| 1 | × | Alternatively, ESP32 Uno-form board | ||
| 1 | × | Alternatively, ESP32 S3 Uno-form board | ||
| 1 | × | Cáp USB Type-C | ||
| 1 | × | Joystick | ||
| 2 | × | động cơ servo | ||
| 2 | × | (Tùy chọn) Bộ kit xoay nghiêng với servo motor | ||
| 1 | × | breadboard | ||
| 1 | × | Dây Jumper | ||
| 1 | × | (Tùy chọn) Jack Nguồn DC | ||
| 1 | × | (Khuyến nghị) Screw Terminal Expansion Board for ESP32 | ||
| 1 | × | (Khuyến nghị) Breakout Expansion Board for ESP32 | ||
| 1 | × | (Khuyến nghị) Power Splitter for ESP32 |
Or you can buy the following kits:
| 1 | × | DIYables ESP32 Starter Kit (ESP32 included) | ||
| 1 | × | DIYables Sensor Kit (30 sensors/displays) | ||
| 1 | × | DIYables Sensor Kit (18 sensors/displays) |
Về Joystick và Servo Motor
Nếu bạn chưa biết về joystick và servo motor (sơ đồ chân, cách hoạt động, cách lập trình ...), hãy tìm hiểu về chúng trong các hướng dẫn sau:
Sơ Đồ Đấu Dây
This image is created using Fritzing. Click to enlarge image
Nếu bạn chưa rõ cách cấp nguồn cho ESP32 và các linh kiện khác, xem: Cách Cung Cấp Nguồn Điện Cho ESP32.
Code ESP32
Code ESP32 - Servo motor xoay theo chuyển động của cần điều khiển joystick
/*
* Mã ESP32 này được phát triển bởi newbiely.vn
* Mã ESP32 này được cung cấp để sử dụng công khai, không có ràng buộc.
* Để xem hướng dẫn chi tiết và sơ đồ kết nối, vui lòng truy cập:
* https://newbiely.vn/tutorials/esp32/esp32-joystick-servo-motor
*/
#include <ESP32Servo.h>
#define VRX_PIN 36 // ESP32 pin GPIO36 (ADC0) connected to VRX pin
#define VRY_PIN 39 // ESP32 pin GPIO39 (ADC0) connected to VRY pin
#define SERVO_X_PIN 13 // ESP32 pin GPIO13 connected to Servo motor 1
#define SERVO_Y_PIN 25 // ESP32 pin GPIO25 connected to Servo motor 2
Servo xServo; // create servo object to control a servo 1
Servo yServo; // create servo object to control a servo 2
void setup() {
Serial.begin(9600);
// Set the ADC attenuation to 11 dB (up to ~3.3V input)
analogSetAttenuation(ADC_11db);
xServo.attach(SERVO_X_PIN);
yServo.attach(SERVO_Y_PIN);
}
void loop() {
// read X and Y analog values
int valueX = analogRead(VRX_PIN);
int valueY = analogRead(VRY_PIN);
int xAngle = map(valueX, 0, 4095, 0, 180); // scale it to the servo's angle (0 to 180)
int yAngle = map(valueY, 0, 4095, 0, 180); // scale it to the servo's angle (0 to 180)
xServo.write(xAngle); // rotate servo motor 1
yServo.write(yAngle); // rotate servo motor 2
// print data to Serial Monitor on Arduino IDE
Serial.print("Joystick: ");
Serial.print(valueX);
Serial.print(", ");
Serial.print(valueY);
Serial.print(" => Servo Motor: ");
Serial.print(xAngle);
Serial.print("°, ");
Serial.print(yAngle);
Serial.println("°");
}
Các Bước Thực Hiện
COM6
Coming soon
Autoscroll
Clear output
9600 baud
Newline
Bạn có thể nhận thấy rằng servo motor không di chuyển tỷ lệ thuận với chuyển động của joystick. Vấn đề này không phải do joystick hay chính servo motor, mà là do ADC của ESP32. Cuối hướng dẫn này sẽ giải thích tại sao điều này xảy ra.
Code ESP32 - Sử dụng joystick để ra lệnh cho servo motor
/*
* Mã ESP32 này được phát triển bởi newbiely.vn
* Mã ESP32 này được cung cấp để sử dụng công khai, không có ràng buộc.
* Để xem hướng dẫn chi tiết và sơ đồ kết nối, vui lòng truy cập:
* https://newbiely.vn/tutorials/esp32/esp32-joystick-servo-motor
*/
#include <ESP32Servo.h>
#include <ezButton.h>
#define VRX_PIN 36 // ESP32 pin GPIO36 (ADC0) connected to VRX pin
#define VRY_PIN 39 // ESP32 pin GPIO39 (ADC0) connected to VRY pin
#define SW_PIN 23 // ESP32 pin GPIO23 connected to SW pin
#define SERVO_X_PIN 13 // ESP32 pin GPIO13 connected to Servo motor 1
#define SERVO_Y_PIN 25 // ESP32 pin GPIO25 connected to Servo motor 2
#define COMMAND_NO 0x00
#define COMMAND_LEFT 0x01
#define COMMAND_RIGHT 0x02
#define COMMAND_UP 0x04
#define COMMAND_DOWN 0x08
#define LEFT_THRESHOLD 1000
#define RIGHT_THRESHOLD 3000
#define UP_THRESHOLD 1000
#define DOWN_THRESHOLD 3000
#define UPDATE_INTERVAL 100 // 100ms
ezButton button(SW_PIN);
Servo xServo; // create servo object to control a servo 1
Servo yServo; // create servo object to control a servo 2
int valueX = 0 ; // to store the X-axis value
int valueY = 0 ; // to store the Y-axis value
int xAngle = 90; // the center position of servo #1
int yAngle = 90; // the center position of servo #2
int command = COMMAND_NO;
unsigned long lastUpdateTime = 0;
void setup() {
Serial.begin(9600);
// Set the ADC attenuation to 11 dB (up to ~3.3V input)
analogSetAttenuation(ADC_11db);
xServo.attach(SERVO_X_PIN);
yServo.attach(SERVO_Y_PIN);
button.setDebounceTime(50); // set debounce time to 50 milliseconds
}
void loop() {
button.loop(); // MUST call the loop() function first
if (millis() - lastUpdateTime > UPDATE_INTERVAL) {
lastUpdateTime = millis() ;
// read X and Y analog values
valueX = analogRead(VRX_PIN);
valueY = analogRead(VRY_PIN);
// converts the analog value to commands
// reset commands
command = COMMAND_NO;
// check left/right commands
if (valueX < LEFT_THRESHOLD)
command = command | COMMAND_LEFT;
else if (valueX > RIGHT_THRESHOLD)
command = command | COMMAND_RIGHT;
// check up/down commands
if (valueY < UP_THRESHOLD)
command = command | COMMAND_UP;
else if (valueY > DOWN_THRESHOLD)
command = command | COMMAND_DOWN;
// NOTE: AT A TIME, THERE MAY BE NO COMMAND, ONE COMMAND OR TWO COMMANDS
// print command to serial and process command
if (command & COMMAND_LEFT) {
Serial.println("COMMAND LEFT");
xAngle--;
}
if (command & COMMAND_RIGHT) {
Serial.println("COMMAND RIGHT");
xAngle++;
}
if (command & COMMAND_UP) {
Serial.println("COMMAND UP");
yAngle--;
}
if (command & COMMAND_DOWN) {
Serial.println("COMMAND DOWN");
yAngle++;
}
}
if (button.isPressed()) {
Serial.println("The button is pressed");
xAngle = 90; // the center position of servo #1
yAngle = 90; // the center position of servo #2
}
xServo.write(xAngle); // rotate servo motor 1
yServo.write(yAngle); // rotate servo motor 2
// print data to Serial Monitor on Arduino IDE
Serial.print("Servo Motor's Angle: ");
Serial.print(xAngle);
Serial.print("°, ");
Serial.print(xAngle);
Serial.println("°");
}
Các Bước Thực Hiện
COM6
Autoscroll
Clear output
9600 baud
Newline
Giải Thích Code
Đọc giải thích từng dòng trong các comment của source code!
※ Lưu ý:
Hướng dẫn này sử dụng hàm analogRead() để đọc giá trị từ ADC (Analog-to-Digital Converter) kết nối với joystick. ADC của ESP32 phù hợp cho các dự án KHÔNG cần độ chính xác cao. Tuy nhiên, đối với các dự án cần phép đo chính xác, xin lưu ý:
Đối với các dự án cần độ chính xác cao, hãy cân nhắc sử dụng ADC ngoài (ví dụ ADS1115) với ESP32 hoặc sử dụng Arduino, có ADC đáng tin cậy hơn. Nếu bạn vẫn muốn hiệu chuẩn ADC của ESP32, tham khảo ESP32 ADC Calibration Driver
Video Tutorial
Việc sản xuất video tốn rất nhiều thời gian. Nếu video hướng dẫn hữu ích cho việc học của bạn, hãy đăng ký kênh YouTube để ủng hộ. Nếu nhu cầu đủ cao, chúng tôi sẽ cố gắng làm thêm nhiều video.